hare-nix/flake.nix

{
  description = "Hare for mac";

  inputs = {
    harec-src = {
      url = "github:badboy/harelang-harec";
      flake = false;
    };
    hare-src = {
      url = "github:badboy/harelang";
      flake = false;
    };
  };

  outputs = { nixpkgs, harec-src, hare-src, ... }:
    let
      supportedSystems = [ "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      devShells = forAllSystems (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          hare-as = pkgs.callPackage ./pkgs/hare-as.nix { };
          hare-cc = pkgs.callPackage ./pkgs/hare-cc.nix { };
          hare-ld = pkgs.callPackage ./pkgs/hare-ld.nix { };
          harec = pkgs.callPackage ./pkgs/harec.nix { inherit harec-src hare-as hare-cc hare-ld; };
          hare = pkgs.callPackage ./pkgs/hare.nix { inherit hare-src harec hare-as hare-cc hare-ld; };
        in
        {
          default = pkgs.mkShell {
            buildInputs = [
              harec
              hare
            ];
          };
        });
    };
}